Veeam ONE: SQL Express Maximum Database Size Limitation

-- Specify the new Retention Policy (how many months to keep, default = 12)
DECLARE @NewRetentionMonths INT = 12;
--
--StrictCleanup value of 0 is recommended for most environments.  Set to 1 for a more aggressive cleanup that will take longer.
DECLARE @StrictCleanup INT = 0;
--
--Do not modify anything below this line!--
SET NOCOUNT ON;

BEGIN TRY
	-- Validate Retention Policy
	IF (@NewRetentionMonths NOT BETWEEN 1 AND 36)
	BEGIN
		RAISERROR('ERROR: The Retention Policy value must be within range of 1-36 months', 15, 15);
		RETURN;
	END

	DECLARE @CurrentRetentionMonths INT = (SELECT TOP 1 COALESCE(RetentionPolicyPeriod, 12) FROM common.ServerSettings);
	PRINT CONCAT('Current Retention Policy: ', @CurrentRetentionMonths, ' months. New Retention Policy: ', @NewRetentionMonths, ' months.');

	IF @NewRetentionMonths < @CurrentRetentionMonths
	BEGIN
		DECLARE @RetentionDate DATETIME = DATEADD(MONTH, -@NewRetentionMonths, GETUTCDATE());
		PRINT CONCAT('Starting the PerfSample data cleanup. Keeping data newer than ', CAST(@RetentionDate AS NVARCHAR));

		-- Cleanup for unpartitioned data
		IF OBJECT_ID(N'[monitor].[PerfSampleLow]', N'U') IS NOT NULL
		BEGIN
			RAISERROR('Clearing unpartitioned data', 0, 1) WITH NOWAIT;
			EXEC monitor.sp_perf_sample_delete 2, @RetentionDate;
			EXEC monitor.sp_perf_sample_delete 3, @RetentionDate;
		END
		ELSE
		BEGIN
			-- Cleanup for partitioned data
			RAISERROR('Clearing partitioned data', 0, 1) WITH NOWAIT;
			DECLARE @partitionName NVARCHAR(32);
			DECLARE cur CURSOR LOCAL FOR
				SELECT 'monitor.' + [name]
				FROM sys.tables
				WHERE name LIKE 'PerfSampleLow%' OR name LIKE 'PerfSampleDay%';

			OPEN cur;
			FETCH NEXT FROM cur INTO @partitionName;

			WHILE @@FETCH_STATUS = 0
			BEGIN
				DECLARE @sql NVARCHAR(MAX);
				
				-- Truncate if applicable
				SET @sql = N'IF (SELECT MAX([timestamp]) FROM ' + @partitionName + ') < @RetentionDate TRUNCATE TABLE ' + @partitionName;
				EXEC sp_executesql @sql, N'@RetentionDate DATETIME', @RetentionDate;

				-- Delete records older than retention date if strict cleanup is enabled
				IF (@StrictCleanup = 1)
				BEGIN
					SET @sql = N'DELETE FROM ' + @partitionName + ' WHERE [timestamp] < @RetentionDate';
					EXEC sp_executesql @sql, N'@RetentionDate DATETIME', @RetentionDate;

					-- Shrink database if applicable
					IF (SELECT recovery_model FROM sys.databases WHERE database_id = DB_ID()) = 3
						DBCC SHRINKDATABASE (0, TRUNCATEONLY) WITH NO_INFOMSGS;
				END

				FETCH NEXT FROM cur INTO @partitionName;
			END
			CLOSE cur;
		END

		PRINT 'PerfSample data cleanup is finished.';
	END

	PRINT 'Updating the Retention Policy parameters.';
	UPDATE common.ServerSettings SET RetentionPolicyPeriod = @NewRetentionMonths;
	PRINT 'Shrinking the Veeam ONE Database file(s).';
	DBCC SHRINKDATABASE (0) WITH NO_INFOMSGS;
	PRINT 'Done!';

END TRY
BEGIN CATCH
	PRINT CONCAT('An error occurred: ', ERROR_MESSAGE());
END CATCH;
GO